From f5c4671bfbad96bf346bd7e9a21fc4317b4959df Mon Sep 17 00:00:00 2001
From: Indrajith K L
Date: Sat, 3 Dec 2022 17:00:20 +0530
Subject: Adds most of the tools

---
 .../runtime/queries/fish/highlights.scm            | 156 +++++++++++++++++++++
 .../runtime/queries/fish/indents.toml              |  12 ++
 .../runtime/queries/fish/injections.scm            |   2 +
 .../runtime/queries/fish/textobjects.scm           |   5 +
 4 files changed, 175 insertions(+)
 create mode 100644 helix-22.03-x86_64-windows/runtime/queries/fish/highlights.scm
 create mode 100644 helix-22.03-x86_64-windows/runtime/queries/fish/indents.toml
 create mode 100644 helix-22.03-x86_64-windows/runtime/queries/fish/injections.scm
 create mode 100644 helix-22.03-x86_64-windows/runtime/queries/fish/textobjects.scm

(limited to 'helix-22.03-x86_64-windows/runtime/queries/fish')

diff --git a/helix-22.03-x86_64-windows/runtime/queries/fish/highlights.scm b/helix-22.03-x86_64-windows/runtime/queries/fish/highlights.scm
new file mode 100644
index 0000000..def5393
--- /dev/null
+++ b/helix-22.03-x86_64-windows/runtime/queries/fish/highlights.scm
@@ -0,0 +1,156 @@
+;; Operators
+
+[
+ "&&"
+ "||"
+ "|"
+ "&"
+ "="
+ "!="
+ ".."
+ "!"
+ (direction)
+ (stream_redirect)
+ (test_option)
+] @operator
+
+[
+ "not"
+ "and"
+ "or"
+] @keyword.operator
+
+;; Conditionals
+
+(if_statement
+[
+ "if"
+ "end"
+] @keyword.control.conditional)
+
+(switch_statement
+[
+ "switch"
+ "end"
+] @keyword.control.conditional)
+
+(case_clause
+[
+ "case"
+] @keyword.control.conditional)
+
+(else_clause 
+[
+ "else"
+] @keyword.control.conditional)
+
+(else_if_clause 
+[
+ "else"
+ "if"
+] @keyword.control.conditional)
+
+;; Loops/Blocks
+
+(while_statement
+[
+ "while"
+ "end"
+] @keyword.control.repeat)
+
+(for_statement
+[
+ "for"
+ "end"
+] @keyword.control.repeat)
+
+(begin_statement
+[
+ "begin"
+ "end"
+] @keyword.control.repeat)
+
+;; Keywords
+
+[
+ "in"
+ (break)
+ (continue)
+] @keyword
+
+"return" @keyword.control.return
+
+;; Punctuation
+
+[
+ "["
+ "]"
+ "{"
+ "}"
+ "("
+ ")"
+] @punctuation.bracket
+
+"," @punctuation.delimiter
+
+;; Commands
+
+(command
+  argument: [
+             (word) @variable.parameter (#match? @variable.parameter "^-")
+            ]
+)
+
+; non-bultin command names
+(command name: (word) @function)
+
+; derived from builtin -n (fish 3.2.2)
+(command
+  name: [
+        (word) @function.builtin
+        (#match? @function.builtin "^(\.|:|_|alias|argparse|bg|bind|block|breakpoint|builtin|cd|command|commandline|complete|contains|count|disown|echo|emit|eval|exec|exit|fg|functions|history|isatty|jobs|math|printf|pwd|random|read|realpath|set|set_color|source|status|string|test|time|type|ulimit|wait)$")
+        ]
+)
+
+(test_command "test" @function.builtin)
+
+;; Functions
+
+(function_definition ["function" "end"] @keyword.function)
+
+(function_definition
+  name: [
+        (word) (concatenation)
+        ] 
+@function)
+
+(function_definition
+  option: [
+          (word)
+          (concatenation (word))
+          ] @variable.parameter (#match? @variable.parameter "^-")
+)
+
+;; Strings
+
+[(double_quote_string) (single_quote_string)] @string
+(escape_sequence) @constant.character.escape
+
+;; Variables
+
+(variable_name) @variable
+(variable_expansion) @constant
+
+;; Nodes
+
+(integer) @constant.numeric.integer
+(float) @constant.numeric.float
+(comment) @comment
+(test_option) @string
+
+((word) @constant.builtin.boolean
+(#match? @constant.builtin.boolean "^(true|false)$"))
+
+;; Error
+
+(ERROR) @error
diff --git a/helix-22.03-x86_64-windows/runtime/queries/fish/indents.toml b/helix-22.03-x86_64-windows/runtime/queries/fish/indents.toml
new file mode 100644
index 0000000..6f1e563
--- /dev/null
+++ b/helix-22.03-x86_64-windows/runtime/queries/fish/indents.toml
@@ -0,0 +1,12 @@
+indent = [
+  "function_definition",
+  "while_statement",
+  "for_statement",
+  "if_statement",
+  "begin_statement",
+  "switch_statement",
+]
+
+outdent = [
+  "end"
+]
diff --git a/helix-22.03-x86_64-windows/runtime/queries/fish/injections.scm b/helix-22.03-x86_64-windows/runtime/queries/fish/injections.scm
new file mode 100644
index 0000000..321c90a
--- /dev/null
+++ b/helix-22.03-x86_64-windows/runtime/queries/fish/injections.scm
@@ -0,0 +1,2 @@
+((comment) @injection.content
+ (#set! injection.language "comment"))
diff --git a/helix-22.03-x86_64-windows/runtime/queries/fish/textobjects.scm b/helix-22.03-x86_64-windows/runtime/queries/fish/textobjects.scm
new file mode 100644
index 0000000..de8caa9
--- /dev/null
+++ b/helix-22.03-x86_64-windows/runtime/queries/fish/textobjects.scm
@@ -0,0 +1,5 @@
+(function_definition) @function.around
+
+(comment) @comment.inside
+
+(comment)+ @comment.around
-- 
cgit v1.2.3