Adds most of the toolsHEADmaster

3 files changed, 388 insertions, 0 deletions

diff --git a/v_windows/v/old/vlib/encoding/base64/base64.v b/v_windows/v/old/vlib/encoding/base64/base64.v
new file mode 100644
index 0000000..203ff0b
--- /dev/null
+++ b/v_windows/v/old/vlib/encoding/base64/base64.v
@@ -0,0 +1,224 @@
+// Copyright (c) 2019-2021 Alexander Medvednikov. All rights reserved.
+// Use of this source code is governed by an MIT license
+// that can be found in the LICENSE file.
+module base64
+
+const (
+	index        = [0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0,
+		0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 62, 63, 62, 62, 63, 52, 53, 54, 55,
+		56, 57, 58, 59, 60, 61, 0, 0, 0, 0, 0, 0, 0, 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12,
+		13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 0, 0, 0, 0, 63, 0, 26, 27, 28, 29,
+		30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51]!
+	ending_table = [0, 2, 1]!
+	enc_table    = 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/'
+)
+
+// decode decodes the base64 encoded `string` value passed in `data`.
+// Please note: If you need to decode many strings repeatedly, take a look at `decode_in_buffer`.
+// Example: assert base64.decode('ViBpbiBiYXNlIDY0') == 'V in base 64'
+pub fn decode(data string) []byte {
+	size := data.len * 3 / 4
+	if size <= 0 || data.len % 4 != 0 {
+		return []
+	}
+	unsafe {
+		buffer := malloc(size)
+		n := decode_in_buffer(data, buffer)
+		return buffer.vbytes(n)
+	}
+}
+
+// decode_str is the string variant of decode
+pub fn decode_str(data string) string {
+	size := data.len * 3 / 4
+	if size <= 0 || data.len % 4 != 0 {
+		return ''
+	}
+	unsafe {
+		buffer := malloc_noscan(size + 1)
+		buffer[size] = 0
+		return tos(buffer, decode_in_buffer(data, buffer))
+	}
+}
+
+// encode encodes the `[]byte` value passed in `data` to base64.
+// Please note: base64 encoding returns a `string` that is ~ 4/3 larger than the input.
+// Please note: If you need to encode many strings repeatedly, take a look at `encode_in_buffer`.
+// Example: assert base64.encode('V in base 64') == 'ViBpbiBiYXNlIDY0'
+pub fn encode(data []byte) string {
+	return alloc_and_encode(data.data, data.len)
+}
+
+// encode_str is the string variant of encode
+pub fn encode_str(data string) string {
+	return alloc_and_encode(data.str, data.len)
+}
+
+// alloc_and_encode is a private function that allocates and encodes data into a string
+// Used by encode and encode_str
+fn alloc_and_encode(src &byte, len int) string {
+	size := 4 * ((len + 2) / 3)
+	if size <= 0 {
+		return ''
+	}
+	unsafe {
+		buffer := malloc_noscan(size + 1)
+		buffer[size] = 0
+		return tos(buffer, encode_from_buffer(buffer, src, len))
+	}
+}
+
+// url_decode returns a decoded URL `string` version of
+// the a base64 url encoded `string` passed in `data`.
+pub fn url_decode(data string) []byte {
+	mut result := data.replace_each(['-', '+', '_', '/'])
+	match result.len % 4 {
+		// Pad with trailing '='s
+		2 { result += '==' } // 2 pad chars
+		3 { result += '=' } // 1 pad char
+		else {} // no padding
+	}
+	return decode(result)
+}
+
+// url_decode_str is the string variant of url_decode
+pub fn url_decode_str(data string) string {
+	mut result := data.replace_each(['-', '+', '_', '/'])
+	match result.len % 4 {
+		// Pad with trailing '='s
+		2 { result += '==' } // 2 pad chars
+		3 { result += '=' } // 1 pad char
+		else {} // no padding
+	}
+	return decode_str(result)
+}
+
+// url_encode returns a base64 URL encoded `string` version
+// of the value passed in `data`.
+pub fn url_encode(data []byte) string {
+	return encode(data).replace_each(['+', '-', '/', '_', '=', ''])
+}
+
+// url_encode_str is the string variant of url_encode
+pub fn url_encode_str(data string) string {
+	return encode_str(data).replace_each(['+', '-', '/', '_', '=', ''])
+}
+
+// decode_in_buffer decodes the base64 encoded `string` reference passed in `data` into `buffer`.
+// decode_in_buffer returns the size of the decoded data in the buffer.
+// Please note: The `buffer` should be large enough (i.e. 3/4 of the data.len, or larger)
+// to hold the decoded data.
+// Please note: This function does NOT allocate new memory, and is thus suitable for handling very large strings.
+pub fn decode_in_buffer(data &string, buffer &byte) int {
+	mut padding := 0
+	if data.ends_with('=') {
+		if data.ends_with('==') {
+			padding = 2
+		} else {
+			padding = 1
+		}
+	}
+	// input_length is the length of meaningful data
+	input_length := data.len - padding
+	output_length := input_length * 3 / 4
+
+	mut i := 0
+	mut j := 0
+	mut b := &byte(0)
+	mut d := &byte(0)
+	unsafe {
+		d = &byte(data.str)
+		b = &byte(buffer)
+	}
+	for i < input_length {
+		mut char_a := 0
+		mut char_b := 0
+		mut char_c := 0
+		mut char_d := 0
+		if i < input_length {
+			char_a = base64.index[unsafe { d[i] }]
+			i++
+		}
+		if i < input_length {
+			char_b = base64.index[unsafe { d[i] }]
+			i++
+		}
+		if i < input_length {
+			char_c = base64.index[unsafe { d[i] }]
+			i++
+		}
+		if i < input_length {
+			char_d = base64.index[unsafe { d[i] }]
+			i++
+		}
+
+		decoded_bytes := (char_a << 18) | (char_b << 12) | (char_c << 6) | (char_d << 0)
+		unsafe {
+			b[j] = byte(decoded_bytes >> 16)
+			b[j + 1] = byte((decoded_bytes >> 8) & 0xff)
+			b[j + 2] = byte((decoded_bytes >> 0) & 0xff)
+		}
+		j += 3
+	}
+	return output_length
+}
+
+// encode_in_buffer base64 encodes the `[]byte` passed in `data` into `buffer`.
+// encode_in_buffer returns the size of the encoded data in the buffer.
+// Please note: The buffer should be large enough (i.e. 4/3 of the data.len, or larger) to hold the encoded data.
+// Please note: The function does NOT allocate new memory, and is suitable for handling very large strings.
+pub fn encode_in_buffer(data []byte, buffer &byte) int {
+	return encode_from_buffer(buffer, data.data, data.len)
+}
+
+// encode_from_buffer will perform encoding from any type of src buffer
+// and write the bytes into `dest`.
+// Please note: The `dest` buffer should be large enough (i.e. 4/3 of the src_len, or larger) to hold the encoded data.
+// Please note: This function is for internal base64 encoding
+fn encode_from_buffer(dest &byte, src &byte, src_len int) int {
+	input_length := src_len
+	output_length := 4 * ((input_length + 2) / 3)
+
+	mut i := 0
+	mut j := 0
+
+	mut d := unsafe { src }
+	mut b := unsafe { dest }
+	mut etable := base64.enc_table.str
+	for i < input_length {
+		mut octet_a := 0
+		mut octet_b := 0
+		mut octet_c := 0
+
+		if i < input_length {
+			octet_a = int(unsafe { d[i] })
+			i++
+		}
+		if i < input_length {
+			octet_b = int(unsafe { d[i] })
+			i++
+		}
+		if i < input_length {
+			octet_c = int(unsafe { d[i] })
+			i++
+		}
+
+		triple := ((octet_a << 0x10) + (octet_b << 0x08) + octet_c)
+
+		unsafe {
+			b[j] = etable[(triple >> 3 * 6) & 63] // 63 is 0x3F
+			b[j + 1] = etable[(triple >> 2 * 6) & 63]
+			b[j + 2] = etable[(triple >> 1 * 6) & 63]
+			b[j + 3] = etable[(triple >> 0 * 6) & 63]
+		}
+		j += 4
+	}
+
+	padding_length := base64.ending_table[input_length % 3]
+	for i = 0; i < padding_length; i++ {
+		unsafe {
+			b[output_length - 1 - i] = `=`
+		}
+	}
+	return output_length
+}
diff --git a/v_windows/v/old/vlib/encoding/base64/base64_memory_test.v b/v_windows/v/old/vlib/encoding/base64/base64_memory_test.v
new file mode 100644
index 0000000..a1ac47a
--- /dev/null
+++ b/v_windows/v/old/vlib/encoding/base64/base64_memory_test.v
@@ -0,0 +1,32 @@
+import encoding.base64
+
+fn test_long_encoding() {
+	repeats := 1000
+	input_size := 3000
+
+	s_original := []byte{len: input_size, init: `a`}
+	s_encoded := base64.encode(s_original)
+	s_decoded := base64.decode(s_encoded)
+
+	assert s_encoded.len > s_original.len
+	assert s_original == s_decoded
+
+	mut s := 0
+
+	ebuffer := unsafe { malloc(s_encoded.len) }
+	for _ in 0 .. repeats {
+		resultsize := base64.encode_in_buffer(s_original, ebuffer)
+		s += resultsize
+		assert resultsize == s_encoded.len
+	}
+
+	dbuffer := unsafe { malloc(s_decoded.len) }
+	for _ in 0 .. repeats {
+		resultsize := base64.decode_in_buffer(s_encoded, dbuffer)
+		s += resultsize
+		assert resultsize == s_decoded.len
+	}
+
+	println('Final s: $s')
+	//	assert s == 39147008
+}
diff --git a/v_windows/v/old/vlib/encoding/base64/base64_test.v b/v_windows/v/old/vlib/encoding/base64/base64_test.v
new file mode 100644
index 0000000..e461330
--- /dev/null
+++ b/v_windows/v/old/vlib/encoding/base64/base64_test.v
@@ -0,0 +1,132 @@
+import encoding.base64
+
+struct TestPair {
+	decoded string
+	encoded string
+}
+
+const (
+	pairs    = [
+		// RFC 3548 examples
+		TestPair{'\x14\xfb\x9c\x03\xd9\x7e', 'FPucA9l+'},
+		TestPair{'\x14\xfb\x9c\x03\xd9', 'FPucA9k='},
+		TestPair{'\x14\xfb\x9c\x03', 'FPucAw=='},
+		// RFC 4648 examples
+		TestPair{'', ''},
+		TestPair{'f', 'Zg=='},
+		TestPair{'fo', 'Zm8='},
+		TestPair{'foo', 'Zm9v'},
+		TestPair{'foob', 'Zm9vYg=='},
+		TestPair{'fooba', 'Zm9vYmE='},
+		TestPair{'foobar', 'Zm9vYmFy'},
+		// Wikipedia examples
+		TestPair{'sure.', 'c3VyZS4='},
+		TestPair{'sure', 'c3VyZQ=='},
+		TestPair{'sur', 'c3Vy'},
+		TestPair{'su', 'c3U='},
+		TestPair{'leasure.', 'bGVhc3VyZS4='},
+		TestPair{'easure.', 'ZWFzdXJlLg=='},
+		TestPair{'asure.', 'YXN1cmUu'},
+		TestPair{'sure.', 'c3VyZS4='},
+	]
+
+	man_pair = TestPair{'Man is distinguished, not only by his reason, but by this singular passion from other animals, which is a lust of the mind, that by a perseverance of delight in the continued and indefatigable generation of knowledge, exceeds the short vehemence of any carnal pleasure.', 'TWFuIGlzIGRpc3Rpbmd1aXNoZWQsIG5vdCBvbmx5IGJ5IGhpcyByZWFzb24sIGJ1dCBieSB0aGlzIHNpbmd1bGFyIHBhc3Npb24gZnJvbSBvdGhlciBhbmltYWxzLCB3aGljaCBpcyBhIGx1c3Qgb2YgdGhlIG1pbmQsIHRoYXQgYnkgYSBwZXJzZXZlcmFuY2Ugb2YgZGVsaWdodCBpbiB0aGUgY29udGludWVkIGFuZCBpbmRlZmF0aWdhYmxlIGdlbmVyYXRpb24gb2Yga25vd2xlZGdlLCBleGNlZWRzIHRoZSBzaG9ydCB2ZWhlbWVuY2Ugb2YgYW55IGNhcm5hbCBwbGVhc3VyZS4='}
+)
+
+fn test_decode() {
+	assert base64.decode(man_pair.encoded) == man_pair.decoded.bytes()
+
+	// Test for incorrect padding.
+	assert base64.decode('aGk') == ''.bytes()
+	assert base64.decode('aGk=') == 'hi'.bytes()
+	assert base64.decode('aGk==') == ''.bytes()
+
+	for i, p in pairs {
+		got := base64.decode(p.encoded)
+		if got != p.decoded.bytes() {
+			eprintln('pairs[$i]: expected = $p.decoded, got = $got')
+			assert false
+		}
+	}
+}
+
+fn test_decode_str() {
+	assert base64.decode_str(man_pair.encoded) == man_pair.decoded
+
+	// Test for incorrect padding.
+	assert base64.decode_str('aGk') == ''
+	assert base64.decode_str('aGk=') == 'hi'
+	assert base64.decode_str('aGk==') == ''
+
+	for i, p in pairs {
+		got := base64.decode_str(p.encoded)
+		if got != p.decoded {
+			eprintln('pairs[$i]: expected = $p.decoded, got = $got')
+			assert false
+		}
+	}
+}
+
+fn test_encode() {
+	assert base64.encode(man_pair.decoded.bytes()) == man_pair.encoded
+
+	for i, p in pairs {
+		got := base64.encode(p.decoded.bytes())
+		if got != p.encoded {
+			eprintln('pairs[$i]: expected = $p.encoded, got = $got')
+			assert false
+		}
+	}
+}
+
+fn test_encode_str() {
+	assert base64.encode_str(man_pair.decoded) == man_pair.encoded
+
+	for i, p in pairs {
+		got := base64.encode_str(p.decoded)
+		if got != p.encoded {
+			eprintln('pairs[$i]: expected = $p.encoded, got = $got')
+			assert false
+		}
+	}
+}
+
+fn test_url_encode() {
+	test := base64.url_encode('Hello Base64Url encoding!'.bytes())
+	assert test == 'SGVsbG8gQmFzZTY0VXJsIGVuY29kaW5nIQ'
+}
+
+fn test_url_encode_str() {
+	test := base64.url_encode_str('Hello Base64Url encoding!')
+	assert test == 'SGVsbG8gQmFzZTY0VXJsIGVuY29kaW5nIQ'
+}
+
+fn test_url_decode() {
+	test := base64.url_decode('SGVsbG8gQmFzZTY0VXJsIGVuY29kaW5nIQ')
+	assert test == 'Hello Base64Url encoding!'.bytes()
+}
+
+fn test_url_decode_str() {
+	test := base64.url_decode_str('SGVsbG8gQmFzZTY0VXJsIGVuY29kaW5nIQ')
+	assert test == 'Hello Base64Url encoding!'
+}
+
+fn test_encode_null_byte() {
+	assert base64.encode([byte(`A`), 0, `C`]) == 'QQBD'
+}
+
+fn test_encode_null_byte_str() {
+	// While this works, bytestr() does a memcpy
+	s := [byte(`A`), 0, `C`].bytestr()
+	assert base64.encode_str(s) == 'QQBD'
+}
+
+fn test_decode_null_byte() {
+	assert base64.decode('QQBD') == [byte(`A`), 0, `C`]
+}
+
+fn test_decode_null_byte_str() {
+	// While this works, bytestr() does a memcpy
+	s := [byte(`A`), 0, `C`].bytestr()
+	assert base64.decode_str('QQBD') == s
+}