2 files changed, 563 insertions, 0 deletions
diff --git a/v_windows/v/old/vlib/rand/pcg32/pcg32.v b/v_windows/v/old/vlib/rand/pcg32/pcg32.v
new file mode 100644
index 0000000..25a83f7
--- /dev/null
+++ b/v_windows/v/old/vlib/rand/pcg32/pcg32.v
@@ -0,0 +1,226 @@
+// Copyright (c) 2019-2021 Alexander Medvednikov. All rights reserved.
+// Use of this source code is governed by an MIT license
+// that can be found in the LICENSE file.
+module pcg32
+
+import rand.seed
+import rand.constants
+
+// PCG32RNG ported from http://www.pcg-random.org/download.html,
+// https://github.com/imneme/pcg-c-basic/blob/master/pcg_basic.c, and
+// https://github.com/imneme/pcg-c-basic/blob/master/pcg_basic.h
+pub struct PCG32RNG {
+mut:
+	state u64 = u64(0x853c49e6748fea9b) ^ seed.time_seed_64()
+	inc   u64 = u64(0xda3e39cb94b95bdb) ^ seed.time_seed_64()
+}
+
+// seed seeds the PCG32RNG with 4 `u32` values.
+// The first 2 represent the 64-bit initial state as `[lower 32 bits, higher 32 bits]`
+// The last 2 represent the 64-bit stream/step of the PRNG.
+pub fn (mut rng PCG32RNG) seed(seed_data []u32) {
+	if seed_data.len != 4 {
+		eprintln('PCG32RNG needs 4 u32s to be seeded. First two the initial state and the last two the stream/step. Both in little endian format: [lower, higher].')
+		exit(1)
+	}
+	init_state := u64(seed_data[0]) | (u64(seed_data[1]) << 32)
+	init_seq := u64(seed_data[2]) | (u64(seed_data[3]) << 32)
+	rng.state = u64(0)
+	rng.inc = (init_seq << u64(1)) | u64(1)
+	rng.u32()
+	rng.state += init_state
+	rng.u32()
+}
+
+// u32 returns a pseudorandom unsigned `u32`.
+[inline]
+pub fn (mut rng PCG32RNG) u32() u32 {
+	oldstate := rng.state
+	rng.state = oldstate * (6364136223846793005) + rng.inc
+	xorshifted := u32(((oldstate >> u64(18)) ^ oldstate) >> u64(27))
+	rot := u32(oldstate >> u64(59))
+	return ((xorshifted >> rot) | (xorshifted << ((-rot) & u32(31))))
+}
+
+// u64 returns a pseudorandom 64-bit unsigned `u64`.
+[inline]
+pub fn (mut rng PCG32RNG) u64() u64 {
+	return u64(rng.u32()) | (u64(rng.u32()) << 32)
+}
+
+// u32n returns a pseudorandom 32-bit unsigned `u32` in range `[0, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) u32n(max u32) u32 {
+	if max == 0 {
+		eprintln('max must be positive')
+		exit(1)
+	}
+	// To avoid bias, we need to make the range of the RNG a multiple of
+	// max, which we do by dropping output less than a threshold.
+	threshold := (-max % max)
+	// Uniformity guarantees that loop below will terminate. In practice, it
+	// should usually terminate quickly; on average (assuming all max's are
+	// equally likely), 82.25% of the time, we can expect it to require just
+	// one iteration. In practice, max's are typically small and only a
+	// tiny amount of the range is eliminated.
+	for {
+		r := rng.u32()
+		if r >= threshold {
+			return (r % max)
+		}
+	}
+	return u32(0)
+}
+
+// u64n returns a pseudorandom 64-bit unsigned `u64` in range `[0, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) u64n(max u64) u64 {
+	if max == 0 {
+		eprintln('max must be positive')
+		exit(1)
+	}
+	threshold := (-max % max)
+	for {
+		r := rng.u64()
+		if r >= threshold {
+			return (r % max)
+		}
+	}
+	return u64(0)
+}
+
+// u32_in_range returns a pseudorandom 32-bit unsigned `u32` in range `[min, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) u32_in_range(min u32, max u32) u32 {
+	if max <= min {
+		eprintln('max must be greater than min')
+		exit(1)
+	}
+	return min + rng.u32n(u32(max - min))
+}
+
+// u64_in_range returns a pseudorandom 64-bit unsigned `u64` in range `[min, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) u64_in_range(min u64, max u64) u64 {
+	if max <= min {
+		eprintln('max must be greater than min')
+		exit(1)
+	}
+	return min + rng.u64n(max - min)
+}
+
+// int returns a 32-bit signed (possibly negative) `int`.
+[inline]
+pub fn (mut rng PCG32RNG) int() int {
+	return int(rng.u32())
+}
+
+// i64 returns a 64-bit signed (possibly negative) `i64`.
+[inline]
+pub fn (mut rng PCG32RNG) i64() i64 {
+	return i64(rng.u64())
+}
+
+// int31 returns a 31-bit positive pseudorandom `int`.
+[inline]
+pub fn (mut rng PCG32RNG) int31() int {
+	return int(rng.u32() >> 1)
+}
+
+// int63 returns a 63-bit positive pseudorandom `i64`.
+[inline]
+pub fn (mut rng PCG32RNG) int63() i64 {
+	return i64(rng.u64() >> 1)
+}
+
+// intn returns a 32-bit positive `int` in range `[0, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) intn(max int) int {
+	if max <= 0 {
+		eprintln('max has to be positive.')
+		exit(1)
+	}
+	return int(rng.u32n(u32(max)))
+}
+
+// i64n returns a 64-bit positive `i64` in range `[0, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) i64n(max i64) i64 {
+	if max <= 0 {
+		eprintln('max has to be positive.')
+		exit(1)
+	}
+	return i64(rng.u64n(u64(max)))
+}
+
+// int_in_range returns a 32-bit positive `int` in range `[0, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) int_in_range(min int, max int) int {
+	if max <= min {
+		eprintln('max must be greater than min.')
+		exit(1)
+	}
+	return min + rng.intn(max - min)
+}
+
+// i64_in_range returns a 64-bit positive `i64` in range `[0, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) i64_in_range(min i64, max i64) i64 {
+	if max <= min {
+		eprintln('max must be greater than min.')
+		exit(1)
+	}
+	return min + rng.i64n(max - min)
+}
+
+// f32 returns a pseudorandom `f32` value in range `[0, 1)`.
+[inline]
+pub fn (mut rng PCG32RNG) f32() f32 {
+	return f32(rng.u32()) / constants.max_u32_as_f32
+}
+
+// f64 returns a pseudorandom `f64` value in range `[0, 1)`.
+[inline]
+pub fn (mut rng PCG32RNG) f64() f64 {
+	return f64(rng.u64()) / constants.max_u64_as_f64
+}
+
+// f32n returns a pseudorandom `f32` value in range `[0, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) f32n(max f32) f32 {
+	if max <= 0 {
+		eprintln('max has to be positive.')
+		exit(1)
+	}
+	return rng.f32() * max
+}
+
+// f64n returns a pseudorandom `f64` value in range `[0, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) f64n(max f64) f64 {
+	if max <= 0 {
+		eprintln('max has to be positive.')
+		exit(1)
+	}
+	return rng.f64() * max
+}
+
+// f32_in_range returns a pseudorandom `f32` in range `[min, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) f32_in_range(min f32, max f32) f32 {
+	if max <= min {
+		eprintln('max must be greater than min')
+		exit(1)
+	}
+	return min + rng.f32n(max - min)
+}
+
+// i64_in_range returns a pseudorandom `i64` in range `[min, max)`.
+[inline]
+pub fn (mut rng PCG32RNG) f64_in_range(min f64, max f64) f64 {
+	if max <= min {
+		eprintln('max must be greater than min')
+		exit(1)
+	}
+	return min + rng.f64n(max - min)
+}
diff --git a/v_windows/v/old/vlib/rand/pcg32/pcg32_test.v b/v_windows/v/old/vlib/rand/pcg32/pcg32_test.v
new file mode 100644
index 0000000..17048a0
--- /dev/null
+++ b/v_windows/v/old/vlib/rand/pcg32/pcg32_test.v
@@ -0,0 +1,337 @@
+import math
+import rand
+import rand.pcg32
+import rand.seed
+
+const (
+	range_limit = 40
+	value_count = 1000
+	seeds       = [[u32(42), 242, 267, 14195], [u32(256), 340, 1451, 1505]]
+)
+
+const (
+	sample_size   = 1000
+	stats_epsilon = 0.05
+	inv_sqrt_12   = 1.0 / math.sqrt(12)
+)
+
+fn gen_randoms(seed_data []u32, bound int) []u32 {
+	mut randoms := []u32{len: 20}
+	mut rng := pcg32.PCG32RNG{}
+	rng.seed(seed_data)
+	for i in 0 .. 20 {
+		randoms[i] = rng.u32n(u32(bound))
+	}
+	return randoms
+}
+
+fn test_pcg32_reproducibility() {
+	seed_data := seed.time_seed_array(4)
+	randoms1 := gen_randoms(seed_data, 1000)
+	randoms2 := gen_randoms(seed_data, 1000)
+	assert randoms1.len == randoms2.len
+	len := randoms1.len
+	for i in 0 .. len {
+		r1 := randoms1[i]
+		r2 := randoms2[i]
+		assert r1 == r2
+	}
+}
+
+// TODO: use the `in` syntax and remove this function
+// after generics has been completely implemented
+fn found(value u64, arr []u64) bool {
+	for item in arr {
+		if value == item {
+			return true
+		}
+	}
+	return false
+}
+
+fn test_pcg32_variability() {
+	// If this test fails and if it is certainly not the implementation
+	// at fault, try changing the seed values. Repeated values are
+	// improbable but not impossible.
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		mut values := []u64{cap: value_count}
+		for i in 0 .. value_count {
+			value := rng.u64()
+			assert !found(value, values)
+			assert values.len == i
+			values << value
+		}
+	}
+}
+
+fn check_uniformity_u64(mut rng pcg32.PCG32RNG, range u64) {
+	range_f64 := f64(range)
+	expected_mean := range_f64 / 2.0
+	mut variance := 0.0
+	for _ in 0 .. sample_size {
+		diff := f64(rng.u64n(range)) - expected_mean
+		variance += diff * diff
+	}
+	variance /= sample_size - 1
+	sigma := math.sqrt(variance)
+	expected_sigma := range_f64 * inv_sqrt_12
+	error := (sigma - expected_sigma) / expected_sigma
+	assert math.abs(error) < stats_epsilon
+}
+
+fn test_pcg32_uniformity_u64() {
+	ranges := [14019545, 80240, 130]
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for range in ranges {
+			check_uniformity_u64(mut rng, u64(range))
+		}
+	}
+}
+
+fn check_uniformity_f64(mut rng pcg32.PCG32RNG) {
+	expected_mean := 0.5
+	mut variance := 0.0
+	for _ in 0 .. sample_size {
+		diff := rng.f64() - expected_mean
+		variance += diff * diff
+	}
+	variance /= sample_size - 1
+	sigma := math.sqrt(variance)
+	expected_sigma := inv_sqrt_12
+	error := (sigma - expected_sigma) / expected_sigma
+	assert math.abs(error) < stats_epsilon
+}
+
+fn test_pcg32_uniformity_f64() {
+	// The f64 version
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		check_uniformity_f64(mut rng)
+	}
+}
+
+fn test_pcg32_u32n() {
+	max := u32(16384)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.u32n(max)
+			assert value >= 0
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_u64n() {
+	max := u64(379091181005)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.u64n(max)
+			assert value >= 0
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_u32_in_range() {
+	max := u32(484468466)
+	min := u32(316846)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.u32_in_range(u32(min), u32(max))
+			assert value >= min
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_u64_in_range() {
+	max := u64(216468454685163)
+	min := u64(6848646868)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.u64_in_range(min, max)
+			assert value >= min
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_int31() {
+	max_u31 := int(0x7FFFFFFF)
+	sign_mask := int(0x80000000)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.int31()
+			assert value >= 0
+			assert value <= max_u31
+			// This statement ensures that the sign bit is zero
+			assert (value & sign_mask) == 0
+		}
+	}
+}
+
+fn test_pcg32_int63() {
+	max_u63 := i64(0x7FFFFFFFFFFFFFFF)
+	sign_mask := i64(0x8000000000000000)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.int63()
+			assert value >= 0
+			assert value <= max_u63
+			assert (value & sign_mask) == 0
+		}
+	}
+}
+
+fn test_pcg32_intn() {
+	max := 2525642
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.intn(max)
+			assert value >= 0
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_i64n() {
+	max := i64(3246727724653636)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.i64n(max)
+			assert value >= 0
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_int_in_range() {
+	min := -4252
+	max := 1034
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.int_in_range(min, max)
+			assert value >= min
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_i64_in_range() {
+	min := i64(-24095)
+	max := i64(324058)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.i64_in_range(min, max)
+			assert value >= min
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_f32() {
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.f32()
+			assert value >= 0.0
+			assert value < 1.0
+		}
+	}
+}
+
+fn test_pcg32_f64() {
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.f64()
+			assert value >= 0.0
+			assert value < 1.0
+		}
+	}
+}
+
+fn test_pcg32_f32n() {
+	max := f32(357.0)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.f32n(max)
+			assert value >= 0.0
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_f64n() {
+	max := 1.52e6
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.f64n(max)
+			assert value >= 0.0
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_f32_in_range() {
+	min := f32(-24.0)
+	max := f32(125.0)
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.f32_in_range(min, max)
+			assert value >= min
+			assert value < max
+		}
+	}
+}
+
+fn test_pcg32_f64_in_range() {
+	min := -548.7
+	max := 5015.2
+	for seed in seeds {
+		mut rng := pcg32.PCG32RNG{}
+		rng.seed(seed)
+		for _ in 0 .. range_limit {
+			value := rng.f64_in_range(min, max)
+			assert value >= min
+			assert value < max
+		}
+	}
+}
+
+fn test_change_default_random_generator() {
+	rand.set_rng(pcg32.PCG32RNG{})
+}