aboutsummaryrefslogtreecommitdiff
path: root/v_windows/v/vlib/crypto/sha512
diff options
context:
space:
mode:
Diffstat (limited to 'v_windows/v/vlib/crypto/sha512')
-rw-r--r--v_windows/v/vlib/crypto/sha512/sha512.v324
-rw-r--r--v_windows/v/vlib/crypto/sha512/sha512_test.v8
-rw-r--r--v_windows/v/vlib/crypto/sha512/sha512block_generic.v108
3 files changed, 440 insertions, 0 deletions
diff --git a/v_windows/v/vlib/crypto/sha512/sha512.v b/v_windows/v/vlib/crypto/sha512/sha512.v
new file mode 100644
index 0000000..dd5d3a9
--- /dev/null
+++ b/v_windows/v/vlib/crypto/sha512/sha512.v
@@ -0,0 +1,324 @@
+// Copyright (c) 2019-2021 Alexander Medvednikov. All rights reserved.
+// Use of this source code is governed by an MIT license
+// that can be found in the LICENSE file.
+// Package sha512 implements the SHA-384, SHA-512, SHA-512/224, and SHA-512/256
+// hash algorithms as defined in FIPS 180-4.
+// Based off: https://github.com/golang/go/tree/master/src/crypto/sha512
+// Last commit: https://github.com/golang/go/commit/3ce865d7a0b88714cc433454ae2370a105210c01
+module sha512
+
+import crypto
+import encoding.binary
+
+pub const (
+ // size is the size, in bytes, of a SHA-512 checksum.
+ size = 64
+ // size224 is the size, in bytes, of a SHA-512/224 checksum.
+ size224 = 28
+ // size256 is the size, in bytes, of a SHA-512/256 checksum.
+ size256 = 32
+ // size384 is the size, in bytes, of a SHA-384 checksum.
+ size384 = 48
+ // block_size is the block size, in bytes, of the SHA-512/224,
+ // SHA-512/256, SHA-384 and SHA-512 hash functions.
+ block_size = 128
+)
+
+const (
+ chunk = 128
+ init0 = u64(0x6a09e667f3bcc908)
+ init1 = u64(0xbb67ae8584caa73b)
+ init2 = u64(0x3c6ef372fe94f82b)
+ init3 = u64(0xa54ff53a5f1d36f1)
+ init4 = u64(0x510e527fade682d1)
+ init5 = u64(0x9b05688c2b3e6c1f)
+ init6 = u64(0x1f83d9abfb41bd6b)
+ init7 = u64(0x5be0cd19137e2179)
+ init0_224 = u64(0x8c3d37c819544da2)
+ init1_224 = u64(0x73e1996689dcd4d6)
+ init2_224 = u64(0x1dfab7ae32ff9c82)
+ init3_224 = u64(0x679dd514582f9fcf)
+ init4_224 = u64(0x0f6d2b697bd44da8)
+ init5_224 = u64(0x77e36f7304c48942)
+ init6_224 = u64(0x3f9d85a86a1d36c8)
+ init7_224 = u64(0x1112e6ad91d692a1)
+ init0_256 = u64(0x22312194fc2bf72c)
+ init1_256 = u64(0x9f555fa3c84c64c2)
+ init2_256 = u64(0x2393b86b6f53b151)
+ init3_256 = u64(0x963877195940eabd)
+ init4_256 = u64(0x96283ee2a88effe3)
+ init5_256 = u64(0xbe5e1e2553863992)
+ init6_256 = u64(0x2b0199fc2c85b8aa)
+ init7_256 = u64(0x0eb72ddc81c52ca2)
+ init0_384 = u64(0xcbbb9d5dc1059ed8)
+ init1_384 = u64(0x629a292a367cd507)
+ init2_384 = u64(0x9159015a3070dd17)
+ init3_384 = u64(0x152fecd8f70e5939)
+ init4_384 = u64(0x67332667ffc00b31)
+ init5_384 = u64(0x8eb44a8768581511)
+ init6_384 = u64(0xdb0c2e0d64f98fa7)
+ init7_384 = u64(0x47b5481dbefa4fa4)
+)
+
+// Digest represents the partial evaluation of a checksum.
+struct Digest {
+mut:
+ h []u64
+ x []byte
+ nx int
+ len u64
+ function crypto.Hash
+}
+
+fn (mut d Digest) reset() {
+ d.h = []u64{len: (8)}
+ d.x = []byte{len: sha512.chunk}
+ match d.function {
+ .sha384 {
+ d.h[0] = sha512.init0_384
+ d.h[1] = sha512.init1_384
+ d.h[2] = sha512.init2_384
+ d.h[3] = sha512.init3_384
+ d.h[4] = sha512.init4_384
+ d.h[5] = sha512.init5_384
+ d.h[6] = sha512.init6_384
+ d.h[7] = sha512.init7_384
+ }
+ .sha512_224 {
+ d.h[0] = sha512.init0_224
+ d.h[1] = sha512.init1_224
+ d.h[2] = sha512.init2_224
+ d.h[3] = sha512.init3_224
+ d.h[4] = sha512.init4_224
+ d.h[5] = sha512.init5_224
+ d.h[6] = sha512.init6_224
+ d.h[7] = sha512.init7_224
+ }
+ .sha512_256 {
+ d.h[0] = sha512.init0_256
+ d.h[1] = sha512.init1_256
+ d.h[2] = sha512.init2_256
+ d.h[3] = sha512.init3_256
+ d.h[4] = sha512.init4_256
+ d.h[5] = sha512.init5_256
+ d.h[6] = sha512.init6_256
+ d.h[7] = sha512.init7_256
+ }
+ else {
+ d.h[0] = sha512.init0
+ d.h[1] = sha512.init1
+ d.h[2] = sha512.init2
+ d.h[3] = sha512.init3
+ d.h[4] = sha512.init4
+ d.h[5] = sha512.init5
+ d.h[6] = sha512.init6
+ d.h[7] = sha512.init7
+ }
+ }
+ d.nx = 0
+ d.len = 0
+}
+
+// internal
+fn new_digest(hash crypto.Hash) &Digest {
+ mut d := &Digest{
+ function: hash
+ }
+ d.reset()
+ return d
+}
+
+// new returns a new Digest (implementing hash.Hash) computing the SHA-512 checksum.
+pub fn new() &Digest {
+ return new_digest(.sha512)
+}
+
+// new512_224 returns a new Digest (implementing hash.Hash) computing the SHA-512/224 checksum.
+fn new512_224() &Digest {
+ return new_digest(.sha512_224)
+}
+
+// new512_256 returns a new Digest (implementing hash.Hash) computing the SHA-512/256 checksum.
+fn new512_256() &Digest {
+ return new_digest(.sha512_256)
+}
+
+// new384 returns a new Digest (implementing hash.Hash) computing the SHA-384 checksum.
+fn new384() &Digest {
+ return new_digest(.sha384)
+}
+
+// write writes the contents of `p_` to the internal hash representation.
+fn (mut d Digest) write(p_ []byte) ?int {
+ unsafe {
+ mut p := p_
+ nn := p.len
+ d.len += u64(nn)
+ if d.nx > 0 {
+ n := copy(d.x[d.nx..], p)
+ d.nx += n
+ if d.nx == sha512.chunk {
+ block(mut d, d.x)
+ d.nx = 0
+ }
+ if n >= p.len {
+ p = []
+ } else {
+ p = p[n..]
+ }
+ }
+ if p.len >= sha512.chunk {
+ n := p.len & ~(sha512.chunk - 1)
+ block(mut d, p[..n])
+ if n >= p.len {
+ p = []
+ } else {
+ p = p[n..]
+ }
+ }
+ if p.len > 0 {
+ d.nx = copy(d.x, p)
+ }
+ return nn
+ }
+}
+
+fn (d &Digest) sum(b_in []byte) []byte {
+ // Make a copy of d so that caller can keep writing and summing.
+ mut d0 := *d
+ hash := d0.checksum()
+ mut b_out := b_in.clone()
+ match d0.function {
+ .sha384 {
+ for b in hash[..sha512.size384] {
+ b_out << b
+ }
+ }
+ .sha512_224 {
+ for b in hash[..sha512.size224] {
+ b_out << b
+ }
+ }
+ .sha512_256 {
+ for b in hash[..sha512.size256] {
+ b_out << b
+ }
+ }
+ else {
+ for b in hash {
+ b_out << b
+ }
+ }
+ }
+ return b_out
+}
+
+fn (mut d Digest) checksum() []byte {
+ // Padding. Add a 1 bit and 0 bits until 112 bytes mod 128.
+ mut len := d.len
+ mut tmp := []byte{len: (128)}
+ tmp[0] = 0x80
+ if int(len) % 128 < 112 {
+ d.write(tmp[..112 - int(len) % 128]) or { panic(err) }
+ } else {
+ d.write(tmp[..128 + 112 - int(len) % 128]) or { panic(err) }
+ }
+ // Length in bits.
+ len <<= u64(3)
+ binary.big_endian_put_u64(mut tmp, u64(0)) // upper 64 bits are always zero, because len variable has type u64
+ binary.big_endian_put_u64(mut tmp[8..], len)
+ d.write(tmp[..16]) or { panic(err) }
+ if d.nx != 0 {
+ panic('d.nx != 0')
+ }
+ mut digest := []byte{len: sha512.size}
+ binary.big_endian_put_u64(mut digest, d.h[0])
+ binary.big_endian_put_u64(mut digest[8..], d.h[1])
+ binary.big_endian_put_u64(mut digest[16..], d.h[2])
+ binary.big_endian_put_u64(mut digest[24..], d.h[3])
+ binary.big_endian_put_u64(mut digest[32..], d.h[4])
+ binary.big_endian_put_u64(mut digest[40..], d.h[5])
+ if d.function != .sha384 {
+ binary.big_endian_put_u64(mut digest[48..], d.h[6])
+ binary.big_endian_put_u64(mut digest[56..], d.h[7])
+ }
+ return digest
+}
+
+// sum512 returns the SHA512 checksum of the data.
+pub fn sum512(data []byte) []byte {
+ mut d := new_digest(.sha512)
+ d.write(data) or { panic(err) }
+ return d.checksum()
+}
+
+// sum384 returns the SHA384 checksum of the data.
+pub fn sum384(data []byte) []byte {
+ mut d := new_digest(.sha384)
+ d.write(data) or { panic(err) }
+ sum := d.checksum()
+ sum384 := []byte{len: sha512.size384}
+ copy(sum384, sum[..sha512.size384])
+ return sum384
+}
+
+// sum512_224 returns the Sum512/224 checksum of the data.
+pub fn sum512_224(data []byte) []byte {
+ mut d := new_digest(.sha512_224)
+ d.write(data) or { panic(err) }
+ sum := d.checksum()
+ sum224 := []byte{len: sha512.size224}
+ copy(sum224, sum[..sha512.size224])
+ return sum224
+}
+
+// sum512_256 returns the Sum512/256 checksum of the data.
+pub fn sum512_256(data []byte) []byte {
+ mut d := new_digest(.sha512_256)
+ d.write(data) or { panic(err) }
+ sum := d.checksum()
+ sum256 := []byte{len: sha512.size256}
+ copy(sum256, sum[..sha512.size256])
+ return sum256
+}
+
+fn block(mut dig Digest, p []byte) {
+ // For now just use block_generic until we have specific
+ // architecture optimized versions
+ block_generic(mut dig, p)
+}
+
+// size returns the size of the checksum in bytes.
+pub fn (d &Digest) size() int {
+ match d.function {
+ .sha512_224 { return sha512.size224 }
+ .sha512_256 { return sha512.size256 }
+ .sha384 { return sha512.size384 }
+ else { return sha512.size }
+ }
+}
+
+// block_size returns the block size of the checksum in bytes.
+pub fn (d &Digest) block_size() int {
+ return sha512.block_size
+}
+
+// hexhash returns a hexadecimal SHA512 hash sum `string` of `s`.
+pub fn hexhash(s string) string {
+ return sum512(s.bytes()).hex()
+}
+
+// hexhash_384 returns a hexadecimal SHA384 hash sum `string` of `s`.
+pub fn hexhash_384(s string) string {
+ return sum384(s.bytes()).hex()
+}
+
+// hexhash_512_224 returns a hexadecimal SHA512/224 hash sum `string` of `s`.
+pub fn hexhash_512_224(s string) string {
+ return sum512_224(s.bytes()).hex()
+}
+
+// hexhash_512_256 returns a hexadecimal 512/256 hash sum `string` of `s`.
+pub fn hexhash_512_256(s string) string {
+ return sum512_256(s.bytes()).hex()
+}
diff --git a/v_windows/v/vlib/crypto/sha512/sha512_test.v b/v_windows/v/vlib/crypto/sha512/sha512_test.v
new file mode 100644
index 0000000..50676d9
--- /dev/null
+++ b/v_windows/v/vlib/crypto/sha512/sha512_test.v
@@ -0,0 +1,8 @@
+// Copyright (c) 2019-2021 Alexander Medvednikov. All rights reserved.
+// Use of this source code is governed by an MIT license
+// that can be found in the LICENSE file.
+import crypto.sha512
+
+fn test_crypto_sha512() {
+ assert sha512.sum512('This is a sha512 checksum.'.bytes()).hex() == '4143e55fcba7e39b20f62a1368e5eb28f64a8859458886117ac66027832e0f9f5263daec688c439d2d0fa07059334668d39e59543039703dbb7e03ec9da7f8d7'
+}
diff --git a/v_windows/v/vlib/crypto/sha512/sha512block_generic.v b/v_windows/v/vlib/crypto/sha512/sha512block_generic.v
new file mode 100644
index 0000000..72a6f5e
--- /dev/null
+++ b/v_windows/v/vlib/crypto/sha512/sha512block_generic.v
@@ -0,0 +1,108 @@
+// Copyright (c) 2019-2021 Alexander Medvednikov. All rights reserved.
+// Use of this source code is governed by an MIT license
+// that can be found in the LICENSE file.
+// SHA512 block step.
+// This is the generic version with no architecture optimizations.
+// In its own file so that an architecture
+// optimized verision can be substituted
+module sha512
+
+import math.bits
+
+const (
+ _k = [u64(0x428a2f98d728ae22), u64(0x7137449123ef65cd), u64(0xb5c0fbcfec4d3b2f), u64(0xe9b5dba58189dbbc),
+ u64(0x3956c25bf348b538), u64(0x59f111f1b605d019), u64(0x923f82a4af194f9b), u64(0xab1c5ed5da6d8118),
+ u64(0xd807aa98a3030242), u64(0x12835b0145706fbe), u64(0x243185be4ee4b28c), u64(0x550c7dc3d5ffb4e2),
+ u64(0x72be5d74f27b896f), u64(0x80deb1fe3b1696b1), u64(0x9bdc06a725c71235), u64(0xc19bf174cf692694),
+ u64(0xe49b69c19ef14ad2), u64(0xefbe4786384f25e3), u64(0x0fc19dc68b8cd5b5), u64(0x240ca1cc77ac9c65),
+ u64(0x2de92c6f592b0275), u64(0x4a7484aa6ea6e483), u64(0x5cb0a9dcbd41fbd4), u64(0x76f988da831153b5),
+ u64(0x983e5152ee66dfab), u64(0xa831c66d2db43210), u64(0xb00327c898fb213f), u64(0xbf597fc7beef0ee4),
+ u64(0xc6e00bf33da88fc2), u64(0xd5a79147930aa725), u64(0x06ca6351e003826f), u64(0x142929670a0e6e70),
+ u64(0x27b70a8546d22ffc), u64(0x2e1b21385c26c926), u64(0x4d2c6dfc5ac42aed), u64(0x53380d139d95b3df),
+ u64(0x650a73548baf63de), u64(0x766a0abb3c77b2a8), u64(0x81c2c92e47edaee6), u64(0x92722c851482353b),
+ u64(0xa2bfe8a14cf10364), u64(0xa81a664bbc423001), u64(0xc24b8b70d0f89791), u64(0xc76c51a30654be30),
+ u64(0xd192e819d6ef5218), u64(0xd69906245565a910), u64(0xf40e35855771202a), u64(0x106aa07032bbd1b8),
+ u64(0x19a4c116b8d2d0c8), u64(0x1e376c085141ab53), u64(0x2748774cdf8eeb99), u64(0x34b0bcb5e19b48a8),
+ u64(0x391c0cb3c5c95a63), u64(0x4ed8aa4ae3418acb), u64(0x5b9cca4f7763e373), u64(0x682e6ff3d6b2b8a3),
+ u64(0x748f82ee5defb2fc), u64(0x78a5636f43172f60), u64(0x84c87814a1f0ab72), u64(0x8cc702081a6439ec),
+ u64(0x90befffa23631e28), u64(0xa4506cebde82bde9), u64(0xbef9a3f7b2c67915), u64(0xc67178f2e372532b),
+ u64(0xca273eceea26619c), u64(0xd186b8c721c0c207), u64(0xeada7dd6cde0eb1e), u64(0xf57d4f7fee6ed178),
+ u64(0x06f067aa72176fba), u64(0x0a637dc5a2c898a6), u64(0x113f9804bef90dae), u64(0x1b710b35131c471b),
+ u64(0x28db77f523047d84), u64(0x32caab7b40c72493), u64(0x3c9ebe0a15c9bebc), u64(0x431d67c49c100d4c),
+ u64(0x4cc5d4becb3e42b6), u64(0x597f299cfc657e2a), u64(0x5fcb6fab3ad6faec), u64(0x6c44198c4a475817)]
+)
+
+fn block_generic(mut dig Digest, p_ []byte) {
+ unsafe {
+ mut p := p_
+ mut w := []u64{len: (80)}
+ mut h0 := dig.h[0]
+ mut h1 := dig.h[1]
+ mut h2 := dig.h[2]
+ mut h3 := dig.h[3]
+ mut h4 := dig.h[4]
+ mut h5 := dig.h[5]
+ mut h6 := dig.h[6]
+ mut h7 := dig.h[7]
+ for p.len >= chunk {
+ for i in 0 .. 16 {
+ j := i * 8
+ w[i] = (u64(p[j]) << 56) |
+ (u64(p[j + 1]) << 48) | (u64(p[j + 2]) << 40) |
+ (u64(p[j + 3]) << 32) | (u64(p[j + 4]) << 24) |
+ (u64(p[j + 5]) << 16) | (u64(p[j + 6]) << 8) | u64(p[j + 7])
+ }
+ for i := 16; i < 80; i++ {
+ v1 := w[i - 2]
+ t1 := bits.rotate_left_64(v1, -19) ^ bits.rotate_left_64(v1, -61) ^ (v1 >> 6)
+ v2 := w[i - 15]
+ t2 := bits.rotate_left_64(v2, -1) ^ bits.rotate_left_64(v2, -8) ^ (v2 >> 7)
+ w[i] = t1 + w[i - 7] + t2 + w[i - 16]
+ }
+ mut a := h0
+ mut b := h1
+ mut c := h2
+ mut d := h3
+ mut e := h4
+ mut f := h5
+ mut g := h6
+ mut h := h7
+ for i in 0 .. 80 {
+ t1 := h +
+ (bits.rotate_left_64(e, -14) ^ bits.rotate_left_64(e, -18) ^ bits.rotate_left_64(e, -41)) +
+ ((e & f) ^ (~e & g)) + _k[i] + w[i]
+ t2 := (bits.rotate_left_64(a, -28) ^ bits.rotate_left_64(a, -34) ^ bits.rotate_left_64(a, -39)) +
+ ((a & b) ^ (a & c) ^ (b & c))
+ h = g
+ g = f
+ f = e
+ e = d + t1
+ d = c
+ c = b
+ b = a
+ a = t1 + t2
+ }
+ h0 += a
+ h1 += b
+ h2 += c
+ h3 += d
+ h4 += e
+ h5 += f
+ h6 += g
+ h7 += h
+ if chunk >= p.len {
+ p = []
+ } else {
+ p = p[chunk..]
+ }
+ }
+ dig.h[0] = h0
+ dig.h[1] = h1
+ dig.h[2] = h2
+ dig.h[3] = h3
+ dig.h[4] = h4
+ dig.h[5] = h5
+ dig.h[6] = h6
+ dig.h[7] = h7
+ }
+}